Разбор вопросов Excel марафона 2026

Вопрос № 1

Если скрыть строки на листе, то любые формулы, ссылающиеся на ячейки в скрытых строках, перестанут работать и будут выдавать ошибку.

Ответ: Ложь

Комментарий: Скрытие строк или столбцов в общем случае никак не влияет на вычисления и не вызывает ошибки. Формулы по‑прежнему видят значения в скрытых ячейках и корректно их обрабатывают. Исключение составляют отдельные функции, которые по своему назначению игнорируют скрытые строки, например, ПРОМЕЖУТОЧНЫЕ.ИТОГИ с определенными номерами операций или АГРЕГАТ с соответствующими аргументами. Стандартные ссылки типа =A1 или обычные функции вроде СУММ, ВПР, СРЗНАЧ продолжают видеть данные в скрытых строках.

Вопрос №2

В Excel можно создать диаграмму только на том же листе, где находятся исходные данные.

Ответ: Ложь

Комментарий: В Excel диаграмму можно создать:

• на том же листе, где находятся исходные данные (внедренная диаграмма);
• на отдельном листе диаграммы, который не содержит ячеек с данными, а представляет собой полноэкранную диаграмму.

Для перемещения существующей диаграммы на отдельный лист используют инструмент: «Работа с диаграммами» → «Конструктор» → «Переместить диаграмму» → Выбрать вариант «на отдельном листе».

Вопрос № 3

При вставке скопированных ячеек можно транспонировать данные, то есть поменять строки и столбцы местами.

Ответ: Правда

Комментарий: Поменять строки и столбцы местами реально. Для этого используют команду «Специальная вставка» (Ctrl+Alt+V). И далее установить флажок «Транспонировать». Также это можно сделать через контекстное меню: «Главная» → «Вставить» → «Транспонировать».

Вопрос № 4

Функция ВПР может искать значение не только в первом столбце таблицы, но и в любом другом, если указать соответствующий номер столбца.

Ответ: Ложь

Комментарий: ВПР всегда ищет значение в первом столбце заданного диапазона. Номер столбца указывает, из какого столбца вернуть результат, но поиск идет только по первому столбцу. Для поиска в любом столбце используют другие функции: ИНДЕКС+ПОИСКПОЗ, ПРОСМОТР (XLOOKUP).

Вопрос № 5

Функция СУММЕСЛИ позволяет суммировать ячейки по одному условию, которое может быть задано числом, текстом или выражением сравнения, например, «>10».

Ответ: Правда

Комментарий: Синтаксис функции выглядит так:
=СУММЕСЛИ(диапазон; условие; [диапазон_суммирования]).
Функция действительно суммирует ячейки, удовлетворяющие одному заданному условию. Условие может быть:

• числом (например, 5 — суммируются ячейки, равные 5);
• текстом (например, "яблоки" — суммируются ячейки с точным совпадением текста, допускается использование подстановочных знаков * и ?);
• выражением сравнения (например, ">10", "< >0", "<=100").

Вопрос № 6

Функция СЖПРОБЕЛЫ удаляет из текста все пробелы, включая одиночные между словами.

Ответ: Ложь

Комментарий: СЖПРОБЕЛЫ удаляет начальные и конечные пробелы, а также заменяет последовательности внутренних пробелов одним пробелом, но не удаляет одиночные пробелы между словами.

Вопрос № 7

В Excel можно настроить условное форматирование так, чтобы автоматически выделять цветом ячейки с повторяющимися значениями.

Ответ: Правда

Комментарий: В условном форматировании есть встроенное правило «Повторяющиеся значения», которое позволяет выделить дубликаты или уникальные значения заданным цветом.

Для этого:

• Выделите нужный диапазон.
• «Главная» → «Условное форматирование» → «Правила выделения ячеек» → «Повторяющиеся значения...».
• В появившемся окне выбрать формат (цвет заливки, цвет шрифта) и нажать ОК.

Вопрос № 8

Именованному диапазону можно присвоить произвольное имя, но затем это имя нельзя использовать в формулах.

Ответ: Ложь

Комментарий: Именованные диапазоны как раз и создают для удобного обращения в формулах. Имя можно применять в вычислениях, например: =СУММ(Продажи), где «Продажи» — именованный диапазон.

Вопрос № 9

В Excel существует функция, которая возвращает количество пустых ячеек в заданном диапазоне.

Ответ: Правда

Комментарий: Функция СЧИТАТЬПУСТОТЫ (COUNTBLANK). Она подсчитывает пустые ячейки в указанном диапазоне.

В подсчет идут ячейки, которые:

• визуально выглядят пустыми;
• не содержат формул, возвращающих пустую строку ("");
• не содержат значений.

Вопрос № 10

Чтобы зафиксировать только строку в формуле (например, при копировании вниз номер строки не менялся, а столбец мог меняться), нужно использовать смешанную ссылку, например, A$1.

Ответ: Правда

Комментарий: Это правда. Знак $ перед номером строки (A$1) фиксирует строку, оставляя столбец относительным. При копировании формулы вниз ссылка останется на ту же строку, а столбец будет изменяться в зависимости от нового положения.

Вопрос № 11

Функция НАЙТИ находит вхождение одной текстовой строки в другой с учетом регистра, т.е. большие и маленькие буквы имеют значение. Это правда или ложь?

Ответ: Правда

Комментарий: Функция НАЙТИ работает с учетом регистра и не позволяет использовать подстановочные знаки. Например:

• =НАЙТИ("А"; "Арбуз") вернет 1
• =НАЙТИ("а"; "Арбуз") вернет ошибку #ЗНАЧ!, так как строчная «а» не найдена в слове, начинающемся с заглавной «А».

Вопрос № 12

В Excel можно защитить от правок только отдельные файлы и вкладки, а ячейки нельзя.

Ответ: Ложь

Комментарий: Это ложь. При установке защиты на лист можно сделать так, чтобы отдельные ячейки остались незащищенными. Например, чтобы человек мог их заполнить своими данными. Чтобы это сделать, следуйте алгоритму:

• Выбрать нужные ячейки, выбрать «Формат ячеек».
• Перейти во вкладку «Защита» и снять галочку с «Защищаемая ячейка», нажать ОК.
• Перейти во вкладку «Рецензирование».
• В меню «Защита» выбрать «Защитить лист».
• Установить пароль для отключения защиты, нажать ОК.

Вопрос № 1

Вы анализируете данные по продажам и хотите узнать общую сумму заказов, которые были отмечены как выполненные, т.е. со статусом «Да». В столбце A указан статус, а в столбце B — сумма заказа. Какие формулы подойдут для этой задачи? Выберите все подходящие варианты.

• =СУММЕСЛИ(A2:A10; "Да"; B2:B10)
• =ЕСЛИ((A2:A10="Да");СУММ(B2:B10))
• =СУММ(A2:A10; "Да"; B2:B10)
• =СУММПРОИЗВ((A2:A10="Да")*B2:B10)

Комментарий. Верные ответы 1 и 4. У функции СУММ нет встроенного условия, поэтому там нужно использовать ЕСЛИ. Значит для решения подойдет стандартная функция для суммирования по одному условию СУММЕСЛИ. Кроме того подойдет СУММПРОИЗВ с логическим умножением — корректно суммирует, перемножая массив логических значений (превращаются в 1 или 0) на значения в столбце B.

Две другие формулы не приведут к нужному результату.

Вопрос № 2

Вы подготовили отчет и скопировали формулу =СУММ(A$1:A10) из ячейки B1 в ячейку C2. Как она изменится после копирования?

• =СУММ(B$1:B10)
• =СУММ(A$1:B10)
• =СУММ(B$1:B11)
• =СУММ(A$1:A11)

Комментарий. Правильный вариант 3. При копировании относительные ссылки сдвигаются: столбец A меняется на B (смещение на 1 вправо), строка 10 увеличивается на 1 (смещение вниз) и становится 11. Строка 1 зафиксирована знаком $ и остается неизменной. Получаем =СУММ(B$1:B11).

Вопрос № 3

Вам нужно сформировать полное имя клиента из отдельных ячеек с фамилией (A1), именем (B1) и отчеством (C1), разделяя их запятыми. Какие формулы подойдут для объединения текста? Выберите все подходящие варианты.

• =СЦЕПИТЬ(A1; ","; B1; ","; C1)
• =ОБЪЕДИНИТЬ(","; ИСТИНА; A1:C1)
• =A1 & "," & B1 & "," & C1
• =СОЕДИНИТЬ(A1; C1; ",")

Комментарий. Правильные ответы 1, 2 и 3. Функции СОЕДИНИТЬ в Экселе не существует. Зато есть остальные три способа.

№1. =СЦЕПИТЬ(A1; ","; B1; ","; C1)
Классическая функция для объединения текста, работает во всех версиях Excel.

№2. =ОБЪЕДИНИТЬ(","; ИСТИНА; A1:C1)
Функция ОБЪЕДИНИТЬ объединяет диапазон с указанным разделителем. Второй аргумент ИСТИНА (или 1) означает, что пустые ячейки игнорируются. Работает в Excel 2019, 2021, 365 и более новых версиях.

№3. =A1 & "," & B1 & "," & C1
Оператор конкатенации & — простой и надежный способ, работает во всех версиях Excel.

Вопрос № 4

Вы готовите отчет для презентации, где числа должны отображаться с двумя знаками после запятой как текст. В ячейке A1 записано значение «123,456». Какие формулы округлят его до двух десятичных знаков и вернут текстовое значение с разделителем-запятой и двумя знаками после запятой? Выберите все подходящие варианты.

• =ТЕКСТ(A1; "0,00")
• =ОКРУГЛ(A1; 2)
• =ФИКСИРОВАННЫЙ(A1; 2)
• =ТЕКСТ(ОКРУГЛ(A1; 2); "0,00")

Комментарий: Правильные варианты 1, 3 и 4. Вариант ОКРУГЛ возвращает число, а не текст. Функции ТЕКСТ и ФИКСИРОВАННЫЙ сразу дают текстовое представление с округлением. Вариант с функцией ТЕКСТ также корректен, хотя избыточен.

Вопрос № 5

Вы работаете с большой таблицей и хотите быстро выделить всю область данных для форматирования. Какую комбинацию клавиш нужно нажать, чтобы выделить всю таблицу в Excel?

• Ctrl + A
• Ctrl + Shift + 7
• Ctrl + Пробел
• Shift + Пробел

Комментарий: Правильный ответ 1. Ctrl + A выделяет текущую область (при повторном нажатии — весь лист).

Вопрос № 6

Вы проверяете заполненность анкет клиентов и хотите узнать, сколько клиентов указали свой номер телефона. Данные о номерах хранят в ячейках A1:A10. Какие формулы подойдут, чтобы посчитать количество непустых ячеек в диапазоне A1:A10? Выберите все верные варианты.

• =СЧЁТ(A1:A10)
• =СЧЁТЗ(A1:A10)
• =СЧИТАТЬПУСТОТЫ(A1:A10)
• =СУММПРОИЗВ(—(A1:A10<>""))

Комментарий: Правильные варианты 2 и 4.

• =СЧЁТЗ(A1:A10). Функция СЧЁТЗ подсчитывает количество непустых ячеек в диапазоне (любые данные: текст, числа, даты, ошибки, формулы, возвращающие значение). Это стандартный инструмент для данной задачи.
• =СУММПРОИЗВ(--(A1:A10<>"")). Формула создает массив логических значений (ИСТИНА для непустых, ЛОЖЬ для пустых), двойное отрицание (--) преобразует их в 1 и 0, а СУММПРОИЗВ суммирует единицы. Результат — количество непустых ячеек.

Остальные варианты некорректны для решения задачи.

Вопрос №7

Какая из перечисленных функций НЕ предназначена для поиска значения в таблице?

• ВПР
• ГПР
• ПРОСМОТР
• ПСТР

Комментарий: Правильные ответ 4. ПСТР — не предназначена для поиска значений в таблице. Это текстовая функция, которая возвращает указанное количество символов из текстовой строки, начиная с заданной позиции.

А вот ВПР, ГПР и ПРОСМОТР — поисковые функции.

• ВПР — предназначена для вертикального поиска значения в первом столбце таблицы с возвратом значения из указанного столбца.
• ГПР — предназначена для горизонтального поиска значения в первой строке таблицы с возвратом значения из указанной строки.
• ПРОСМОТР — функция для поиска значения в однострочном или одностолбцовом диапазоне либо в массиве.

Вопрос №8

В ячейке A1 записана дата 01.01.2026. В ячейку B1 написали формулу «=МЕСЯЦ(A1) + 15». У ячейки стоит формат Общий. Какое значение отобразится в ячейке?

• 1
• 16
• Дата 16.01.2026
• #ЗНАЧ!
• #ПУСТО!

Комментарий: Правильный ответ 2. Функция МЕСЯЦ возвращает номер месяца (число от 1 до 12). Для 1 января это 1, затем прибавляет 15, получаем 16. Результат — обычное число, не дата.

Вопрос №9

Перед вами список товаров с артикулами в формате «Товар#12345», где после символа «#» всегда идет пятизначный цифровой код. Артикулы записаны в столбце А. Какая формула позволит извлечь только цифровую часть «12345»?

• =ПРАВСИМВ(A1; 6)
• =ПСТР(A1; 7; 5)
• =ЗАМЕНИТЬ(A1; "#"; 6; "")
• =ПОДСТРОКА(A1;"#";5)

Комментарий: Правильный ответ 2. Вариант с ПСТР: берет 5 символов с 7-й позиции. ПРАВСИМВ берет последние 6 символов с конца, а не 5, как нужно. Функции ПОДСТРОКА в Эксель не существует. У функции ЗАМЕНИТЬ неверный синтаксис: вместо начальной позиции, указан "#", что вызовет ошибку.

Вопрос №10

Вы работаете с таблицей Excel, где по строкам идут филиалы компании, а по столбцам расположены данные о выручке этих филиалов по месяцам. Одна беда: месяцы в столбцах идут не в календарном порядке, а произвольно. Можно ли в Excel сделать сортировку по столбцам, чтобы расположить месяцы в календарном порядке и проанализировать динамику?

• Нет, нельзя. Сортировку можно делать только по строкам.
• Да, можно, но только через «Транспонирование» и дальнейшую сортировку по строкам.
• Да, можно, но только через макрос.
• Да, можно. Через «Данные» → «Сортировка».

Комментарий: Правильный ответ 4. Да, в Excel есть стандартный инструмент сортировать данные по столбцам, а не только по строкам. Поэтому варианты ответов только через «Транспонирование» или макрос — некорректны и избыточны для решения поставленной задачи.

Вопрос № 11

Вы импортировали данные из внешнего источника, и в столбце A даты отображаются как числа (например, 45678). Как быстро преобразовать весь столбец в формат даты?

• Выделить столбец, нажать Ctrl+Shift+9.
• Выделить столбец, нажать Ctrl+1, выбрать формат «Дата» и нужный тип.
• Выделить столбец, на вкладке «Главная» выбрать в выпадающем списке форматов «Краткий формат даты».
• Использовать функцию =ПРЕОБР(...)

Комментарий: Правильные ответы 2 и 3.

• Выделить столбец, нажать Ctrl+1, выбрать формат «Дата» и нужный тип. Это стандартный способ через диалоговое окно «Формат ячеек». Корректно преобразует числовое значение (количество дней с 01.01.1900) в отображение даты.
• Выделить столбец, на вкладке «Главная» выбрать в выпадающем списке форматов «Краткий формат даты». Быстрый способ через ленту. Достаточно выделить столбец и выбрать нужный формат даты из выпадающего списка в группе «Число». Это также корректно.

Вопрос №12

Вам предстоит написать формулу, которая будет ссылаться на ячейку, имя которой формируется динамически, например, из текста в другой ячейке. Какая функция для этого подходит?

• АДРЕС
• ДВССЫЛ
• СМЕЩ
• ИНДЕКС

Комментарий: Правильный ответ 2. ДВССЫЛ преобразует текстовое представление ссылки в реальную ссылку. АДРЕС возвращает текст адреса, СМЕЩ возвращает диапазон по смещениям, ИНДЕКС возвращает значение или ссылку по номерам строки и столбца.

Вопрос № 13

Вы анализируете финансовый отчет, а коллега жалуется, что при копировании формулы «=СУММ(A1:A10)+B1*B2» в другой лист Excel выдает ошибку. В чем может быть проблема? Выберите верный вариант.

• Excel не позволяет использовать СУММ() с диапазоном больше 5 строк в одной формуле.
• Ошибка происходит, потому что B1*B2 должно быть записано как =УМНОЖ(B1;B2).
• Формула содержит относительные ссылки, которые могут некорректно работать при копировании на другой лист.
• Excel блокирует вычисления, если в файле больше 1000 строк.

Комментарий: Правильный ответ 3. В Excel нет ограничения для функции СУММ(), так что вариант с ограничением отпадает. Ячейки можно умножать напрямую, функция УМНОЖ не нужна. Объем данных в Excel не влияет на формулы. Остается один вариант — относительные ссылки. Чтобы исправить ситуацию, нужно использовать абсолютные ссылки: =СУММ($A$1:$A$10)+$B$1*$B$2

Вопрос № 14

У вас несколько магазинов одежды в разных городах. Одежду продаете разную: спортивную, повседневную, для походов и так далее. Вам пришли данные о продажах и возвратах в магазинах. Какая формула определит выручку в магазине «Петербург» за вычетом возвратов?

• =СУММЕСЛИ(A2:A13;"Петербург*";C2:C13)-СУММЕСЛИ(A2:A13;"Петербург*";B2:B13)
• =СУММЕСЛИ(A2:A13;Петербург;B2:B13)-СУММЕСЛИ(A2:A13;Петербург;C2:C13)
• =СУММЕСЛИ(A2:A13;"Петербург*";B2:B13)-СУММЕСЛИ(A2:A13;"Петербург*";C2:C13)
• =СУММЕСЛИ(A2:A13;"Петербург*";C2:C13)+СУММЕСЛИ(A2:A13;"Петербург*";B2:B13)
• =СУММЕСЛИ(A2:A13;"Петербург*";B2:B13)

Комментарий: Правильный ответ 3. Выручка за вычетом возвратов = сумма продаж минус сумма возвратов.

• В столбце A — названия магазинов (в том числе «Петербург»).
• В столбце B — сумма продаж.
• В столбце C — сумма возвратов.

Почему не подходят другие варианты:

• =СУММЕСЛИ(A2:A13;"Петербург*";C2:C13)-СУММЕСЛИ(A2:A13;"Петербург*";B2:B13) — вычитает продажи из возвратов, получится отрицательное значение (убыток), а не выручка.
• =СУММЕСЛИ(A2:A13;Петербург;B2:B13)-СУММЕСЛИ(A2:A13;Петербург;C2:C13) — условие Петербург без кавычек вызовет ошибку #ИМЯ?, так как Excel воспримет это как неопределенное имя. Также нет звёздочки, что может не охватить все варианты названий.
• =СУММЕСЛИ(A2:A13;"Петербург*";C2:C13)+СУММЕСЛИ(A2:A13;"Петербург*";B2:B13) — складывает продажи и возвраты, что не соответствует выручке за вычетом возвратов.
• =СУММЕСЛИ(A2:A13;"Петербург*";B2:B13) — учитывает только продажи, без вычета возвратов.

Вопрос № 15

Вы ввели формулу =ВПР("Иванов"; A2:B10; 2; 0). В столбце A действительно есть значение «Иванов», но формула выдает #Н/Д. Что могло пойти не так? Выберите наиболее вероятную причину.

• Регистр букв не совпадает (например, «иванов»).
• В ячейке с «Иванов» есть невидимые пробелы в начале или конце.
• В диапазон A2:B10 включена шапка таблицы (строка с заголовком).
• Номер столбца указан неверно (должен быть 1).

Комментарий: Правильный ответ 2. ВПР не чувствителен к регистру, поэтому вариант 1 не подходит. Номер столбца 2 верен, если нужно вернуть значение из столбца B. Наличие шапки не мешает поиску, если искомое значение находится в данных. Наиболее вероятная причина — лишние пробелы, в том числе неразрывные, в ячейке с искомым значением.

Вопрос № 16

Вам нужно определить, кто из сотрудников получит премию по итогам года. У вас есть такая таблица:

В ячейке Е нужно написать слово «Премия», если сотрудник:

• из отдела Продажи и продажи > 500000
• ИЛИ
• из отдела Финансы и стаж ≥ 4

Какая формула в ячейке E2 правильно определит, положена ли премия?

• =ЕСЛИ(И(B2="Продажи";D2>500000;B2="Финансы";C2>=4);"Премия";"Нет")
• =ЕСЛИ(ИЛИ(B2="Продажи";D2>500000;C2>=4);"Премия";"Нет")
• =ЕСЛИ(И(B2="Продажи";ИЛИ(D2>500000;C2>=4));"Премия";"Нет")
• =ЕСЛИ(ИЛИ(И(B2="Продажи";D2>500000);И(B2="Финансы";C2>=4));"Премия";"Нет")
• Нет правильного варианта ответа

Комментарий: Правильный ответ 4.
=ЕСЛИ(ИЛИ(И(B2="Продажи";D2>500000);И(B2="Финансы";C2>=4));"Премия";"Нет")

Логика условия. Премию дают, если выполнено хотя бы одно из двух условий:

• Отдел = «Продажи» И продажи > 500 000
• Отдел = «Финансы» И стаж ≥ 4

В формуле:

• И(B2="Продажи";D2>500000) — первое составное условие
• И(B2="Финансы";C2>=4) — второе составное условие
• ИЛИ(... ; ...) — объединяет их по принципу «или»

Все это внутри ЕСЛИ возвращает «Премия» или «Нет»

Почему не подходят остальные варианты:

• =ЕСЛИ(И(B2="Продажи";D2>500000;B2="Финансы";C2>=4);"Премия";"Нет"). Здесь используется И для всех условий одновременно. Это означало бы, что сотрудник должен одновременно быть и из «Продажи», и из «Финансы», что невозможно. Условие никогда не выполнится.
• =ЕСЛИ(ИЛИ(B2="Продажи";D2>500000;C2>=4);"Премия";"Нет"). Условие слишком широкое: премия будет выдана, если отдел «Продажи» ИЛИ продажи > 500 000 ИЛИ стаж ≥ 4. Это не соответствует исходному требованию (например, сотрудник из отдела «Финансы» с продажами > 500 000, но стажем 2 года получил бы премию, хотя не должен).
• =ЕСЛИ(И(B2="Продажи";ИЛИ(D2>500000;C2>=4));"Премия";"Нет"). Означает: отдел «Продажи» И (продажи > 500 000 ИЛИ стаж ≥ 4). Для отдела «Финансы» условие не сработает вообще, так как первая часть B2="Продажи" не выполнится.

Вопрос №17

Вы работаете с таблицей Excel, где хранят данные о выручке магазинов за каждый день. Вы хотите суммировать всю выручку с помощью функции СУММ. Вводите в строку формул «=СУ», и Excel предлагает функции на выбор, первая из которых как раз «СУММ». Какую клавишу или комбинацию клавиш нажать, чтобы автоматически дописать функцию?

• Alt
• Tab
• Shift
• Shift+пробел
• Ctrl+Shift

Комментарий: Правильный ответ 2. Автоматически дописать функцию поможет клавиша Tab. С помощью горячих клавиш можно не только быстро писать формулы, но и удобно и быстро перемещаться по таблице или документу. Например, клавиша Home переводит курсор в начало строки, End — в конец строки.

Вопрос № 18

Вы анализируете продажи напитков в разных регионах. Какие формулы посчитают количество заказов кофе и чая в регионе Север? Выберите все подходящие варианты.

• =СУММПРОИЗВ((A2:A12="Кофе")*(B2:B12="Север")*(C2:C12))
• =СУММПРОИЗВ(((A2:A12="Кофе")+(A2:A12="Чай"))*(B2:B12="Север")*(C2:C12))
• =СУММЕСЛИМН(C2:C12;A2:A12;"Кофе";A2:A12;"Чай";B2:B12;"Север")
• =СУММПРОИЗВ((A2:A12="Кофе")*(A2:A12="Чай")*(B2:B12="Север")*(C2:C12))
• =СУММ(СУММЕСЛИМН(C2:C12;A2:A12;{"Чай";"Кофе"};B2:B12;"Север"))

Комментарий: Правильные варианты 2 и 5.

=СУММПРОИЗВ(((A2:A12="Кофе")+(A2:A12="Чай"))*(B2:B12="Север")*(C2:C12)). Здесь + работает как логическое «ИЛИ» для условий по напиткам. Для строк, где напиток = «Кофе» или «Чай» и регион = «Север», перемножаются соответствующие значения из столбца C (количество заказов). СУММПРОИЗВ суммирует результат.

=СУММ(СУММЕСЛИМН(C2:C12;A2:A12;{"Чай";"Кофе"};B2:B12;"Север")). Функция СУММЕСЛИМН с массивом условий {"Чай";"Кофе"} возвращает массив из двух чисел (сумма заказов для чая и для кофе отдельно), а СУММ складывает их. Это корректный и эффективный способ.

Почему не подходят остальные варианты:

• =СУММПРОИЗВ((A2:A12="Кофе")*(B2:B12="Север")*(C2:C12)). Учитывает только напиток «Кофе», без «Чай». Условие неполное.
• =СУММЕСЛИМН(C2:C12;A2:A12;"Кофе";A2:A12;"Чай";B2:B12;"Север"). СУММЕСЛИМН требует одновременного выполнения всех условий. Одна и та же ячейка в столбце A не может одновременно равняться и «Кофе», и «Чай». Формула всегда вернет 0.
• =СУММПРОИЗВ((A2:A12="Кофе")*(A2:A12="Чай")*(B2:B12="Север")*(C2:C12)) Условия ="Кофе" и ="Чай" перемножаются, что дает 0 для всех строк (одна ячейка не может удовлетворять обоим условиям одновременно). Результат всегда 0.

Вопрос № 19

Что произойдет, если выбрать несколько ячеек, в том числе несмежных, ввести слово «Просрочено» и нажать Ctrl+Enter?

• Во всех выбранных ячейках удалится подстрока «Просрочено».
• Excel подсчитает общее количество слов «Просрочено» со всех выбранных ячейках.
• Слово «Просрочено» появится во всех выбранных ячейках.
• Excel выведет ошибку: «Неподходящий тип данных».
• Все выбранные ячейки будут удалены со сдвигом вверх.

Комментарий: Правильный ответ 3. Мы можем выбрать любое количество ячеек в разных местах, ввести данные, нажать Ctrl+Enter и эти данные появятся во всех отмеченных ячейках. Остальные варианты некорректны.

Вопрос № 20

В столбце А хранятся ФИО клиентов, они записаны полностью, например «Федоров Иван Максимович». Вам нужно в столбце В преобразовать полное имя в формат с инициалами: Фамилия И.О. Какая комбинация клавиш позволяет автоматически заполнить столбец по шаблону?

• CTRL + SHIFT +U
• CTRL + Y
• CTRL + M
• CTRL+ E

Справка от эксперта:

• CTRL + SHIFT + U — Разворачивает/сворачивает строку формул.Если формула длинная, эта комбинация увеличит или уменьшит размер поля ввода.
• CTRL + Y — Повтор последнего действия.
• CTRL + M — Ничего не делает в Excel.

Комментарий: Верный ответ 4. CTRL+ E — Флеш-заполнение (Flash Fill). Excel анализирует паттерны в данных и автоматически заполняет столбец.

Вопрос № 21

Выберите верное утверждение про работу функции ЕОШ:

• Функцию ЕОШ используют для проверки ячейки на ошибки.
• Функция ЕОШ это усовершенствованная функция ЕСЛИОШИБКА.
• Функция ЕОШ определяет #Н/Д как ошибку.
• Такой функции не существует.

Комментарий: Верный ответ 3. Функция ЕОШ возвращает ИСТИНА, если значение является ошибкой (кроме #Н/Д), и ЛОЖЬ в противном случае. Ее действительно используют для проверки ячеек на наличие ошибок.

Объяснение эксперта. Почему не подходят остальные варианты:

• Функция ЕОШ это усовершенствованная функция ЕСЛИОШИБКА. Неверно. ЕОШ — это логическая функция, которая возвращает ИСТИНА/ЛОЖЬ. ЕСЛИОШИБКА — это функция-обработчик, которая возвращает заданное значение вместо ошибки. Они разные по назначению и синтаксису.
• Функция ЕОШ определяет #Н/Д как ошибку. Неверно. ЕОШ не считает #Н/Д ошибкой. Для определения #Н/Д используют функцию ЕНД. Если нужно определить любую ошибку (включая #Н/Д), применяют ЕОШИБКА.
• Такой функции не существует. Неверно. Функция ЕОШ существует во всех версиях Excel.

Вопрос № 22

В отчете требуется округлить значения до десятых. В ячейке А10 хранится дробное число 123,49. Какую формулу нужно написать в ячейку B10, чтобы округлить число до десятых и получить 123,5?

• =ОКРУГЛВНИЗ(A10;1)
• =ОКРУГЛ(A10;1)
• =ОКРУГЛВВЕРХ(A10;2)
• =ОКРУГЛТ(A10;1)

Комментарий: Правильный ответ 2. Функция ОКРУГЛ округляет число до указанного количества десятичных знаков по правилам математического округления: =ОКРУГЛ(123,49; 1) → 123,5

Почему не подходят другие варианты:

• =ОКРУГЛВНИЗ(A10;1) — округляет число в меньшую сторону. 123,49 → 123,4
• =ОКРУГЛВВЕРХ(A10;2) — округляет вверх до двух десятичных знаков, что не соответствует задаче. 123,49 → 123,49
• =ОКРУГЛТ(A10;1) — функция ОКРУГЛТ округляет число до ближайшего кратного указанному числу. В данном случае =ОКРУГЛТ(123,49; 1) округлит до ближайшего целого, а не до десятых. Для округления до десятых нужно использовать =ОКРУГЛТ(A10; 0,1).

Вопрос № 23

С помощью каких горячих клавиш можно быстро добавить фильтр в таблице Excel? Выберите верный вариант:

• CTRL + M
• CTRL + ALT + K
• CTRL + SHIFT + L
• SHIFT + L

Комментарий: Верный ответ 3. CTRL + SHIFT + L — Включает/выключает автофильтр на текущем диапазоне данных. Остальные клавиши из списка ничего не делают в Excel. остальные сочетания не вызывают добавление фильтра.

Задача № 1

Откройте вкладку «Обучение» в скачанной рабочей таблице. В таблице по строкам идут ФИО сотрудников, которые проходили обучающие курсы, а в столбцах баллы по итогам тестирования по соответствующему курсу. Если в ячейке пусто, значит сотрудник пропустил обучение. Посчитайте какое количество курсов совокупно прошли все сотрудники. Ответ введите цифрами без пробелов, например:234

Правильный ответ: 125. Здесь пригодится функция СЧЁТ — она как раз считает количество числовых значений (то есть непустых ячеек) в диапазоне. Получится такая формула: =СЧЁТ(B2:F37). В итоге количество пройденных курсов (непустых ячеек) равно 125.

Задача № 2

Откройте вкладку «Товары» в таблице. Представьте, вы работаете в торговой компании. У вас есть таблица из следующих полей:

• Номер заказа: уникальный номер каждого заказа.
• Клиент: имя клиента, сделавшего заказ.
• Товар: наименование приобретенного товара.
• Количество: количество приобретенных единиц товара.
• Цена за единицу (руб.): стоимость каждой единицы товара в рублях.

Рассчитайте общую выручку компании. Введите ответ цифрами без пробелов, без запятых, без точек и без копеек. Пример: 215456

Правильный ответ: 517500

Допустимые варианты ответа:

• 517500
• 517 500
• 517 500
• 517500
• 517 500
• 517 500

Комментарий. Сначала посчитаем выручку по каждому товару. Составим формулу для ячейки F2, а затем растянем её на весь столбец, чтобы не заполнять вручную. Чтобы посчитать выручку по товару, нужно умножить количество на цену. Получится такая формула: =D2*E2

Растягиваем формулу на весь столбец F. Осталось суммировать все выручки. Для этого в соседней ячейке воспользуемся функцией СУММ и укажем диапазон суммирования: =СУММ(F2:F31)

Вот и все! Итоговая сумма равна 517500. Кстати, так как мы суммируем весь столбец F, то вместо диапазона можно просто щелкнуть на имя столбца. В результате получится такая формула: =СУММ(F:F)

Так мы можем посчитать сумму по всему столбцу, причем Excel сам будет игнорировать названия столбцов, если такие есть. Только убедитесь, что формула не написана в столбце F, иначе будет ошибка.

Задача №3

Откройте вкладку «Продажи» в таблице. У вас есть таблица по продажам в регионах. Она состоит из полей:

• Регион — «Центр», «Северо-Запад», «Юг», «Волга», «Урал», «Сибирь», «Дальний Восток»,
• Менеджер — ФИО,
• Товар — наименование,
• Количество — целое число,
• Цена — руб., с копейками,
• Дата — в формате ДД.ММ.ГГГГ.

Определите, сколько регионов имеют выручку выше средней выручки по всем регионам. В ответ введите это число цифрами без пробелов, без запятых, без точек и без копеек. Пример: 5

Верный ответ: 3. Вычислим выручку для каждой строки/ Добавим столбец G «Выручка» с формулой:
=D2*E2. Растянем формулу на все строки. Далее найдем сумму выручки по каждому региону через сводную таблицу:

• Выделите любую ячейку в данных → Вставка → Сводная таблица.
• В строки перетащите поле «Регион», в значения — поле «Выручка» (сумма).

После вычислим среднюю выручку по регионам в ячейке G10. Допустим, полученные суммы находятся в новом листе в диапазоне B2:B8. Формула среднего: =СРЗНАЧ(B2:B8). Результат = 264520.

Подсчитаем количество регионов с выручкой выше среднего. Используем формулу =СЧЁТЕСЛИ(B2:B8;">"&G10) (где G10 — ячейка со средним). Итого: 3 региона.

Задача № 4

Откройте вкладку «Доставка» в скачанной рабочей таблице. В таблице прописаны данные:

• A — Номер заказа (целое),
• B — Город отправления (текст),
• C — Город назначения (текст),
• D — Расстояние (км, целое число),
• E — Вес груза (кг, число с одним знаком после запятой),
• F — Тариф (руб. за км за кг, число с тремя знаками после запятой, например 0.150).

Найдите среднюю стоимость доставки для заказов, у которых расстояние больше 500 км. Ответ округлите до целого числа по правилам математического округления. Формула расчета стоимости доставки: Стоимость доставки = Расстояние × Вес × Тариф. Ответ введите цифрами без пробелов, например: 456

Верный ответ: 443. Добавим столбец «Стоимость», это столбец G. В ячейку G2 введите формулу: =D2*E2*F2. Скопируйте ее на все строки с данными. Далее вычислим среднюю стоимость для заказов с расстоянием > 500 км. Для этого используем функцию СРЗНАЧЕСЛИ в ячейке H2: =СРЗНАЧЕСЛИ(D2:D61; «>500»; G2:G61). Результат получится 442,9832353. Округлим результат до целого числа с помощью функции ОКРУГЛ: =ОКРУГЛ(H2; 0). Получаем 443.

Вопрос №5

Откройте вкладку «Сотрудники» в скачанной рабочей таблице. Посчитайте общую сумму зарплат аналитиков, которым больше 30 лет. Ответ введите цифрами без пробелов, например:456000.

Правильный ответ: 957000. Эту задачу можно было бы решить через несколько функций ЕСЛИ и кучу формул. Однако на самом деле задача решается быстро и просто через одну функцию — СУММЕСЛИМН. В ее названии кроется решение: сумма значений, которые удовлетворяют сразу нескольким условиям. Получится такая формула: =СУММЕСЛИМН(D:D;B:B;"Аналитик";C:C;">30")

• D:D — диапазон суммирования, т.е. зарплаты
• B:B — диапазон первого условия: проверяем должность
• "Аналитик" — прописываем условие для первого диапазона: нам нужны аналитики
• C:C — диапазон второго условия: проверяем возраст
• ">30" — прописываем условие для первого диапазона: нам нужны строго старше 30 лет

В итоге по формуле получаем ответ 957000.

Вопрос № 6

Откройте вкладку «Сотрудники» в скачанной рабочей таблице. Подсчитайте стаж работы каждого сотрудника и в поле ответа введите максимальный стаж. Стаж считаем на 1 апреля 2026 года. В поле для ответа введите количество полных лет, которые отработал сотрудник или сотрудники с максимальным стажем. Ответ введите цифрами без пробелов, например: 5.

Верный ответ: 9. Возможные вариации: с пробелами до и после. Сначала посчитаем стаж каждого сотрудника в отдельном столбце F на 1 апреля 2026 года. В этом поможет формула, которая выведет количество полных лет стажа на заданную дату: =РАЗНДАТ(E2; ДАТА(2026;4;1); "Y").

Далее находим максимум по формуле: =МАКС(F2:F29). Получаем, что максимальный стаж 9 лет.

Вопрос № 7

Откройте вкладку «Бренды» в скачанной рабочей таблице. Вы оцениваете эффективность рекламной кампании. Рекламировались различные бренды одежды, и надо оценить привлеченные благодаря рекламе продажи по каждому из брендов. В исходных данных статистика по продажам относится к поисковому запросу. Запрос содержит в себе не только название бренда, но также другие уточняющие слова. Определите общую сумму продаж бренда NIKE. Ответ введите цифрами без пробелов, например: 4567235

Верный ответ: 2078838. Чтобы посчитать сумму продаж конкретного бренда нам нужно понять, есть ли в запросе слово NIKE. Если нет — выдать ошибку и вывести 0, то есть не учитывать выручку по строке. Если есть — вывести сумму.

Сначала решим проблему с выводом ошибки. Для этого воспользуемся функцией ЕОШ — она выводит ИСТИНА, если ошибка есть, или ЛОЖЬ, если ошибки нет: =(ЕОШ(НАЙТИ("NIKE";A2))

Если просто растянуть формулу, то везде будет просто ИСТИНА и ЛОЖЬ. А нам нужно посчитать сумму продаж. Значит, нужно заменить логические значения на числа. Получается, если получаем ИСТИНА, то это ошибка, а значит нужно вывести 0. А если получаем ЛОЖЬ, то ошибки нет, т.е. мы нашли запрос с NIKE, а значит выводим сумму продажи. Уточняем формулу: =ЕСЛИ(ЕОШ(НАЙТИ("NIKE";A2));0;B2)

Вот и все! Растягиваем формулу и затем находим сумму по получившемуся столбцу: =СУММ(C:C). Общая сумма продаж бренда NIKE составила 2 078 838 руб.

Хотите освоить возможности нейросетей и получать максимально точные ответы с первого раза. Приходите на курс «Нейросеть. Базовый курс» обучаться премудростям работы с искусственным интеллектом под наставничеством опытных экспертов.